linux-user: Implement safe_syscall for 64-bit ARM

Implement the host assembly fragment needed for safe_syscall
for 64-bit ARM.

Signed-off-by: Peter Maydell <peter.maydell@linaro.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/linux-user/host/aarch64/hostdep.h b/linux-user/host/aarch64/hostdep.h
index 7609bf5cd7..e2c28e6ea6 100644
--- a/linux-user/host/aarch64/hostdep.h
+++ b/linux-user/host/aarch64/hostdep.h
@@ -12,4 +12,27 @@
 #ifndef QEMU_HOSTDEP_H
 #define QEMU_HOSTDEP_H
 
+/* We have a safe-syscall.inc.S */
+#define HAVE_SAFE_SYSCALL
+
+#ifndef __ASSEMBLER__
+
+/* These are defined by the safe-syscall.inc.S file */
+extern char safe_syscall_start[];
+extern char safe_syscall_end[];
+
+/* Adjust the signal context to rewind out of safe-syscall if we're in it */
+static inline void rewind_if_in_safe_syscall(void *puc)
+{
+    struct ucontext *uc = puc;
+    unsigned long long *pcreg = &uc->uc_mcontext.pc;
+
+    if (*pcreg > (uintptr_t)safe_syscall_start
+        && *pcreg < (uintptr_t)safe_syscall_end) {
+        *pcreg = (uintptr_t)safe_syscall_start;
+    }
+}
+
+#endif /* __ASSEMBLER__ */
+
 #endif
diff --git a/linux-user/host/aarch64/safe-syscall.inc.S b/linux-user/host/aarch64/safe-syscall.inc.S
new file mode 100644
index 0000000000..2c21489e66
--- /dev/null
+++ b/linux-user/host/aarch64/safe-syscall.inc.S
@@ -0,0 +1,78 @@
+/*
+ * safe-syscall.inc.S : host-specific assembly fragment
+ * to handle signals occurring at the same time as system calls.
+ * This is intended to be included by linux-user/safe-syscall.S
+ *
+ *  * Written by Peter Maydell <peter.maydell@linaro.org>
+ *
+ * Copyright (C) 2016 Linaro Limited
+ *
+ * This work is licensed under the terms of the GNU GPL, version 2 or later.
+ * See the COPYING file in the top-level directory.
+ */
+
+    .global safe_syscall_base
+    .global safe_syscall_start
+    .global safe_syscall_end
+    .type   safe_syscall_base, %function
+    .align  4
+
+    /* This is the entry point for making a system call. The calling
+     * convention here is that of a C varargs function with the
+     * first argument an 'int *' to the signal_pending flag, the
+     * second one the system call number (as a 'long'), and all further
+     * arguments being syscall arguments (also 'long').
+     * We return a long which is the syscall's return value, which
+     * may be negative-errno on failure. Conversion to the
+     * -1-and-errno-set convention is done by the calling wrapper.
+     */
+safe_syscall_base:
+    .cfi_startproc
+
+    /* The syscall calling convention isn't the same as the
+     * C one:
+     * we enter with x0 == *signal_pending
+     *           x1 == syscall number
+     *           x2, x3, x4, x5, x6, x7 == syscall arguments
+     *           and return the result in x0
+     * and the syscall instruction needs
+     *           x8 == syscall number
+     *           x0, x1, x2, x3, x4, x5 == syscall arguments
+     *           and returns the result in r0
+     * Shuffle everything around appropriately.
+     */
+    mov x9, x0 /* signal-pending pointer */
+    mov x8, x1 /* syscall number */
+    /* and the syscall arguments */
+    mov x0, x2
+    mov x1, x3
+    mov x2, x4
+    mov x3, x5
+    mov x4, x6
+    mov x5, x7
+
+    /* This next sequence of code works in conjunction with the
+     * rewind_if_safe_syscall_function(). If a signal is taken
+     * and the interrupted PC is anywhere between 'safe_syscall_start'
+     * and 'safe_syscall_end' then we rewind it to 'safe_syscall_start'.
+     * The code sequence must therefore be able to cope with this, and
+     * the syscall instruction must be the final one in the sequence.
+     */
+safe_syscall_start:
+    /* if signal_pending is non-zero, don't do the call */
+    ldr w10, [x9]
+    cmp w10, #0
+    b.ne return_ERESTARTSYS
+    svc 0x0
+safe_syscall_end:
+    /* code path for having successfully executed the syscall */
+    /* NB: we assume we're not trying to do old ARMv4T interworking */
+    ret
+
+return_ERESTARTSYS:
+    /* code path when we didn't execute the syscall */
+    mov x0, #-TARGET_ERESTARTSYS
+    ret
+    .cfi_endproc
+
+    .size   safe_syscall_base, .-safe_syscall_base