aboutsummaryrefslogtreecommitdiff
path: root/meta-linaro/recipes-kernel/perf/perf.bbappend
blob: 0b52f7c3474f8d05ec72033f1185e8f0d9342740 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
LICENSE = "GPL-2"
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"

PV = "3.17"

FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
SRC_URI = "${DEBIAN_MIRROR}/main/l/linux-tools/linux-tools_3.17.orig.tar.xz \
           file://0001-perf-tools-Fix-arm64-build-error.patch \
           file://0001-perf-tools-Fix-build-breakage-on-arm64-targets.patch \
"

SRC_URI[md5sum] = "6c78f25c86761a60b89235e12bc109a8"
SRC_URI[sha256sum] = "51162320841053fcf06070b6d5a6d984fb4c429e3ba3dc6d4eec021d374b926f"

S = "${WORKDIR}/linux-tools-${PV}"
B = "${WORKDIR}/linux-tools-${PV}"

do_compile_prepend() {
    mkdir -p ${S}/include/generated
    echo "#define UTS_RELEASE \"${PV}\"" > ${S}/include/generated/utsrelease.h
}

# Ensure the above tarball gets fetched, unpackaged and patched
python () {
	d.delVarFlag("do_fetch", "noexec")
	d.delVarFlag("do_unpack", "noexec")
	d.delVarFlag("do_patch", "noexec")
}