aboutsummaryrefslogtreecommitdiff
path: root/arch/arm/lib/strnlen_user.S
blob: 0ecbb459c4f1e7c5c2b653db312291584ca10310 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
/*
 *  linux/arch/arm/lib/strnlen_user.S
 *
 *  Copyright (C) 1995-2000 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */
#include <linux/linkage.h>
#include <asm/assembler.h>
#include <asm/errno.h>

	.text
	.align	5

/* Prototype: unsigned long __strnlen_user(const char *str, long n)
 * Purpose  : get length of a string in user memory
 * Params   : str - address of string in user memory
 * Returns  : length of string *including terminator*
 *	      or zero on exception, or n + 1 if too long
 */
ENTRY(__strnlen_user)
	mov	r2, r0
1:
	ldrusr	r3, r0, 1
	teq	r3, #0
	beq	2f
	subs	r1, r1, #1
	bne	1b
	add	r0, r0, #1
2:	sub	r0, r0, r2
	mov	pc, lr
ENDPROC(__strnlen_user)

	.pushsection .fixup,"ax"
	.align	0
9001:	mov	r0, #0
	mov	pc, lr
	.popsection