aboutsummaryrefslogtreecommitdiff
path: root/arch/i386/cpu/start.S
blob: 7def8def8b1d3b2398343fe0efbdc8cd935597b5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
/*
 *  U-boot - i386 Startup Code
 *
 *  Copyright (c) 2002	Omicron Ceti AB, Daniel Engstrm <denaiel@omicron.se>
 *
 * See file CREDITS for list of people who contributed to this
 * project.
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 * MA 02111-1307 USA
 */


#include <config.h>
#include <version.h>


.section .text
.code32
.globl _start
.type _start, @function
.globl _i386boot_start
_i386boot_start:
	/*
	 * This is the fail safe 32-bit bootstrap entry point. The
	 * following code is not executed from a cold-reset (actually, a
	 * lot of it is, but from real-mode after cold reset. It is
	 * repeated here to put the board into a state as close to cold
	 * reset as necessary)
	 */
	cli
	cld

	/* Turn of cache (this might require a 486-class CPU) */
	movl	%cr0, %eax
	orl	$0x60000000,%eax
	movl	%eax, %cr0
	wbinvd

	/* Tell 32-bit code it is being entered from an in-RAM copy */
	movw	$0x0000, %bx
_start:
	/* This is the 32-bit cold-reset entry point */

	movl    $0x18,%eax	/* Load our segement registes, the
				 * gdt have already been loaded by start16.S */
	movw    %ax,%fs
	movw	%ax,%ds
	movw    %ax,%gs
	movw    %ax,%es
	movw    %ax,%ss

	/* Clear the interupt vectors */
	lidt	blank_idt_ptr

	/*
	 * Skip low-level board and memory initialization if not starting
	 * from cold-reset. This allows us to do a fail safe boot-strap
	 * into a new build of U-Boot from a known-good boot flash
	 */
	movw	$0x0001, %ax
	cmpw	%ax, %bx
	jne	mem_init_ret

	/* We call a few functions in the board support package
	 * since we have no stack yet we'll have to use %ebp
	 * to store the return address */

	/* Early platform init (setup gpio, etc ) */
	mov     $early_board_init_ret, %ebp
	jmp	early_board_init
early_board_init_ret:

	/* The __port80 entry-point should be usabe by now */
	/* so we try to indicate progress */
	movw	$0x01, %ax
	movl	$.progress0, %ebp
	jmp	show_boot_progress_asm
.progress0:

	/* size memory */
	mov	$mem_init_ret, %ebp
	jmp     mem_init
mem_init_ret:

	/* fetch memory size (into %eax) */
	mov	$get_mem_size_ret, %ebp
	jmp     get_mem_size
get_mem_size_ret:

	/*
	 * We are now in 'Flat Protected Mode' and we know how much memory
	 * the board has. The (temporary) Global Descriptor Table is not
	 * in a 'Safe' place (it is either in Flash which can be erased or
	 * reprogrammed or in a fail-safe boot-strap image which could be
	 * over-written).
	 *
	 * Move the final gdt to a safe place (top of RAM) and load it.
	 * This is not a trivial excercise - the lgdt instruction does not
	 * have a register operand (memory only) and we may well be
	 * running from Flash, so self modifying code will not work here.
	 * To overcome this, we copy a stub into upper memory along with
	 * the GDT.
	 */

	/* Reduce upper memory limit by (Stub + GDT Pointer + GDT) */
	subl	$(end_gdt_setup - start_gdt_setup), %eax

	/* Copy the GDT and Stub */
	movl	$start_gdt_setup, %esi
	movl	%eax, %edi
	movl	$(end_gdt_setup - start_gdt_setup), %ecx
	shrl	$2, %ecx
	cld
	rep	movsl

	/* write the lgdt 'parameter' */
	subl	$(jmp_instr - start_gdt_setup - 4), %ebp
	addl	%eax, %ebp
	movl	$(gdt_ptr - start_gdt_setup), %ebx
	addl	%eax, %ebx
	movl	%ebx, (%ebp)

	/* write the gdt address into the pointer */
	movl	$(gdt_addr - start_gdt_setup), %ebp
	addl	%eax, %ebp
	movl	$(gdt - start_gdt_setup), %ebx
	addl	%eax, %ebx
	movl	%ebx, (%ebp)

	/* Save the return address */
	movl	$load_gdt_ret, %ebp

	/* Load the new (safe) Global Descriptor Table */
	jmp	*%eax

load_gdt_ret:
	/* Check we have enough memory for stack */
	movl	$CONFIG_SYS_STACK_SIZE, %ecx
	cmpl	%ecx, %eax
	jae	mem_ok

	/* indicate (lack of) progress */
	movw	$0x81, %ax
	movl	$.progress0a, %ebp
	jmp	show_boot_progress_asm
.progress0a:
	jmp	die
mem_ok:
	/* Set stack pointer to upper memory limit*/
	movl    %eax, %esp

	/* indicate progress */
	movw	$0x02, %ax
	movl	$.progress1, %ebp
	jmp	show_boot_progress_asm
.progress1:

	/* Test the stack */
	pushl	$0
	popl	%eax
	cmpl	$0, %eax
	jne	no_stack
	push	$0x55aa55aa
	popl	%ebx
	cmpl	$0x55aa55aa, %ebx
	je	stack_ok

no_stack:
	/* indicate (lack of) progress */
	movw	$0x82, %ax
	movl	$.progress1a, %ebp
	jmp	show_boot_progress_asm
.progress1a:
	jmp die


stack_ok:
	/* indicate progress */
	movw	$0x03, %ax
	movl	$.progress2, %ebp
	jmp	show_boot_progress_asm
.progress2:

	wbinvd

	/* Get upper memory limit */
	movl %esp, %ecx
	subl $CONFIG_SYS_STACK_SIZE, %ecx

	/* Create a Stack Frame */
	pushl %ebp
	movl %esp, %ebp

	/* stack_limit parameter */
	pushl	%ecx
	call	board_init_f	/* Enter, U-boot! */

	/* indicate (lack of) progress */
	movw	$0x85, %ax
	movl	$.progress4a, %ebp
	jmp	show_boot_progress_asm
.progress4a:

die:	hlt
	jmp	die
	hlt

blank_idt_ptr:
	.word	0		/* limit */
	.long	0		/* base */

.align 4
start_gdt_setup:
	lgdt	gdt_ptr
jmp_instr:
	jmp	*%ebp

.align 4
gdt_ptr:
	.word	0x30		/* limit (48 bytes = 6 GDT entries) */
gdt_addr:
	.long	gdt		/* base */

	/* The GDT table ...
	 *
	 *	 Selector	Type
	 *	 0x00		NULL
	 *	 0x08		Unused
	 *	 0x10		32bit code
	 *	 0x18		32bit data/stack
	 *	 0x20		16bit code
	 *	 0x28		16bit data/stack
	 */

.align 4
gdt:
	.word	0, 0, 0, 0	/* NULL  */
	.word	0, 0, 0, 0	/* unused */

	.word	0xFFFF		/* 4Gb - (0x100000*0x1000 = 4Gb) */
	.word	0		/* base address = 0 */
	.word	0x9B00		/* code read/exec */
	.word	0x00CF		/* granularity = 4096, 386 (+5th nibble of limit) */

	.word	0xFFFF		/* 4Gb - (0x100000*0x1000 = 4Gb) */
	.word	0x0		/* base address = 0 */
	.word	0x9300		/* data read/write */
	.word	0x00CF		/* granularity = 4096, 386 (+5th nibble of limit) */

	.word	0xFFFF		/* 64kb */
	.word	0		/* base address = 0 */
	.word	0x9b00		/* data read/write */
	.word	0x0010		/* granularity = 1  (+5th nibble of limit) */

	.word	0xFFFF		/* 64kb */
	.word	0		/* base address = 0 */
	.word	0x9300		/* data read/write */
	.word	0x0010		/* granularity = 1 (+5th nibble of limit) */
end_gdt_setup: