recipes-security/optee/optee-examples: Add optee-examples bitbake recipe

This bitbake recipe builds the OPTEE examples trusted applications.

Change-Id: Ifa2eceaade882cf08eb481b46aa86c9114147f33
Signed-off-by: Bryan O'Donoghue <bryan.odonoghue@linaro.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/meta-optee/recipes-security/optee/optee-examples.bb b/meta-optee/recipes-security/optee/optee-examples.bb
new file mode 100644
index 00000000..f586fe95
--- /dev/null
+++ b/meta-optee/recipes-security/optee/optee-examples.bb
@@ -0,0 +1,42 @@
+SUMMARY = "OP-TEE examples"
+HOMEPAGE = "https://github.com/linaro-swg/optee_examples"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=cd95ab417e23b94f381dafc453d70c30"
+
+DEPENDS = "optee-client optee-os python-pycrypto-native"
+
+inherit pythonnative
+
+SRC_URI = "git://github.com/linaro-swg/optee_examples.git"
+SRCREV = "1c5d96fb2f6abab232bc06705fe557bc4f76964b"
+
+S = "${WORKDIR}/git"
+
+OPTEE_CLIENT_EXPORT = "${STAGING_DIR_HOST}${prefix}"
+TEEC_EXPORT = "${STAGING_DIR_HOST}${prefix}"
+TA_DEV_KIT_DIR = "${STAGING_INCDIR}/optee/export-user_ta"
+
+EXTRA_OEMAKE = " TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
+                 OPTEE_CLIENT_EXPORT=${OPTEE_CLIENT_EXPORT} \
+                 TEEC_EXPORT=${TEEC_EXPORT} \
+                 HOST_CROSS_COMPILE=${TARGET_PREFIX} \
+                 TA_CROSS_COMPILE=${TARGET_PREFIX} \
+                 V=1 \
+               "
+
+do_compile() {
+    oe_runmake
+}
+
+do_install () {
+    mkdir -p ${D}${nonarch_base_libdir}/optee_armtz
+    mkdir -p ${D}${bindir}
+    install -D -p -m0755 ${S}/out/ca/* ${D}${bindir}
+    install -D -p -m0444 ${S}/out/ta/* ${D}${nonarch_base_libdir}/optee_armtz
+}
+
+FILES_${PN} += "${nonarch_base_libdir}/optee_armtz/"
+
+# Imports machine specific configs from staging to build
+PACKAGE_ARCH = "${MACHINE_ARCH}"